How to control the temperature of your terrarium remotely - The Cheap Way

This is the last step. In order to complete the coding of the Wemos D1 we will need:

• Google Apps Script ID
• Wi-Fi Name
• Wi-Fi Password 

You can find the Google App Script ID in the link that you just saved. (https://script.google.com/macros/s/~~~Google Apps Script~~~/exec)

 
#include "TickTwo.h"
#include "ESP8266WiFi.h"
#include "HTTPSRedirect.h"
#include "DebugMacros.h"
#include "OneWire.h"
#include "DallasTemperature.h"

// Data wire is plugged into port D2 on the ESP8266
#define ONE_WIRE_BUS D2

OneWire oneWire(ONE_WIRE_BUS);
DallasTemperature sensors(&oneWire);


float m = 30; // intervall in minutes
float in = m * 60000;
void push();
TickTwo timer(push, in );

float t;
String sheetTemp = "";

const char* ssid = "WiFi Name"; //WiFi Name
const char* password = "WiFi Password"; //WiFi Password
const char* deviceName = "Device name"; //Device name

const char* host = "script.google.com";
const char *GScriptId = "scipt ID"; //scipt ID
const int httpsPort = 443;
const char* fingerprint = "";

// Write to Google Spreadsheet
String url = String("/macros/s/") + GScriptId + "/exec?";

String payload = "";

HTTPSRedirect* client = nullptr;

void setup() {
  Serial.begin(115200);
  timer.start();
  sensors.begin();
  Serial.println(in);
  Serial.flush();

  Serial.println();
  Serial.print("Connecting to wifi: ");
  Serial.println(ssid);
  Serial.flush();
  WiFi.mode(WIFI_STA);
  WiFi.hostname(deviceName);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());

  client = new HTTPSRedirect(httpsPort);
  client->setInsecure();
  client->setPrintResponseBody(true);
  client->setContentTypeHeader("application/json");

  Serial.print("Connecting to ");
  Serial.println(host);

  bool flag = false;
  for (int i = 0; i < 5; i++) {
    int retval = client->connect(host, httpsPort);
    if (retval == 1) {
      flag = true;
      break;
    }
    else
      Serial.println("Connection failed. Retrying...");
  }

  if (!flag) {
    Serial.print("Could not connect to server: ");
    Serial.println(host);
    Serial.println("Exiting...");
    return;
  }

  delete client;
  client = nullptr;

}

void loop() {
  timer.update();
}

void push() {
  Serial.println("Start of Push Function");

  Serial.print("Requesting temperatures...");
  sensors.requestTemperatures(); // Send the command to get temperatures
  Serial.println("DONE");
  float t = sensors.getTempCByIndex(0);
  if (t != DEVICE_DISCONNECTED_C)
  {
    Serial.print("Temperature for the device is: ");
    Serial.println(t);
  }
  else
  {
    Serial.println("Error: Could not read temperature data");
  }
  sheetTemp = String(t);

  payload = sheetTemp;

  static int error_count = 0;
  static int connect_count = 0;
  const unsigned int MAX_CONNECT = 20;
  static bool flag = false;

  if (!flag) {
    client = new HTTPSRedirect(httpsPort);
    client->setInsecure();
    flag = true;
    client->setPrintResponseBody(true);
    client->setContentTypeHeader("application/json");
  }


  if (client != nullptr) {
    if (!client->connected()) {
      client->connect(host, httpsPort);
    }
  }
  else {
    DPRINTLN("Error creating client object!");
    error_count = 5;
  }

  if (connect_count > MAX_CONNECT) {
    connect_count = 0;
    flag = false;
    delete client;
  }

  if (client->POST(url, host, payload, false)) {
    Serial.println("Uploading temperature to Google Sheet");
  }
  else {
    ++error_count;
    DPRINT("Error-count while connecting: ");
    DPRINTLN(error_count);
  }

  if (error_count > 3) {
    Serial.println("Halting processor...");
    delete client;
    client = nullptr;
    Serial.flush();
  }
  delete client;
  client = nullptr;
  flag = false;
  Serial.println("End of Push Function");
}